Tutoriel Terraform (2e génération)

Configurer votre environnement

Dans ce tutoriel, vous exécutez des commandes dans Cloud Shell. Cloud Shell est un environnement de shell dans lequel la Google Cloud CLI est déjà installée avec des valeurs prédéfinies pour votre projet actuel. L'initialisation de Cloud Shell peut prendre quelques minutes.

Ouvrir Cloud Shell

Préparer l'application

Dans Cloud Shell, procédez comme suit :

1. Clonez le dépôt de l'exemple d'application sur votre instance Cloud Shell:

   git clone https://github.com/GoogleCloudPlatform/nodejs-docs-samples.git

2. Accédez au répertoire contenant les exemples de code Cloud Functions :

   cd nodejs-docs-samples/functions

   L'exemple Node.js utilisé dans ce tutoriel est une fonction HTTP de base "Hello World".

Créer le fichier main.tf

1. Dans le répertoire nodejs-docs-samples/functions/, créez un fichier main.tf pour la configuration Terraform:

   touch main.tf
   

2. Copiez cette configuration Terraform dans votre fichier main.tf:

   terraform {
     required_providers {
       google = {
         source  = "hashicorp/google"
         version = ">= 4.34.0"
       }
     }
   }
   
   resource "random_id" "default" {
     byte_length = 8
   }
   
   resource "google_storage_bucket" "default" {
     name                        = "${random_id.default.hex}-gcf-source" # Every bucket name must be globally unique
     location                    = "US"
     uniform_bucket_level_access = true
   }
   
   data "archive_file" "default" {
     type        = "zip"
     output_path = "/tmp/function-source.zip"
     source_dir  = "functions/hello-world/"
   }
   resource "google_storage_bucket_object" "object" {
     name   = "function-source.zip"
     bucket = google_storage_bucket.default.name
     source = data.archive_file.default.output_path # Add path to the zipped function source code
   }
   
   resource "google_cloudfunctions2_function" "default" {
     name        = "function-v2"
     location    = "us-central1"
     description = "a new function"
   
     build_config {
       runtime     = "nodejs16"
       entry_point = "helloHttp" # Set the entry point
       source {
         storage_source {
           bucket = google_storage_bucket.default.name
           object = google_storage_bucket_object.object.name
         }
       }
     }
   
     service_config {
       max_instance_count = 1
       available_memory   = "256M"
       timeout_seconds    = 60
     }
   }
   
   resource "google_cloud_run_service_iam_member" "member" {
     location = google_cloudfunctions2_function.default.location
     service  = google_cloudfunctions2_function.default.name
     role     = "roles/run.invoker"
     member   = "allUsers"
   }
   
   output "function_uri" {
     value = google_cloudfunctions2_function.default.service_config[0].uri
   }

3. Modifiez le fichier main.tf pour vous assurer qu'il contient les valeurs adéquates pour les éléments suivants. Vous devez modifier ce fichier chaque fois que votre configuration change (par exemple, pour utiliser un environnement d'exécution différent ou déployer une fonction différente):

   • Environnement d'exécution : dans cet exemple, remplacez nodejs16 par l'environnement d'exécution Node.js le plus récent (nodejs20).
   • Point d'entrée de la fonction : dans cet exemple, le point d'entrée de la fonction est helloHttp.
   • Chemin d'accès au répertoire source : dans cet exemple, remplacez source_dir par helloworld/helloworldHttp.
   • La configuration IAM member="allUsers" échoue si votre projet est soumis à une règle d'administration de restriction de domaine limitant l'attribution de rôles IAM au compte principal allUsers. Utilisez-la avec précaution en production et envisagez une liste de membres plus restreinte, le cas échéant.

Initialiser Terraform

Dans le répertoire nodejs-docs-samples/functions/ contenant votre fichier main.tf, exécutez cette commande pour ajouter les plug-ins nécessaires et créez le répertoire .terraform :

terraform init

Appliquer la configuration Terraform

Dans le répertoire nodejs-docs-samples/functions/ contenant votre fichier main.tf, déployez la fonction en appliquant la configuration. Lorsque vous y êtes invité, saisissez yes :

terraform apply

Tester la fonction

1. Une fois le déploiement de la fonction terminé, notez la propriété URI ou recherchez-la à l'aide de la commande suivante :

   gcloud functions describe function-v2 --gen2 --region=us-central1 --format="value(serviceConfig.uri)"
   

2. Envoyez une requête à cette URL pour afficher le message "Hello World" de votre fonction. Notez que la fonction est déployée en nécessitant une authentification. Par conséquent, vous devez fournir des identifiants dans votre requête:

   curl -H "Authorization: Bearer $(gcloud auth print-identity-token)" YOUR_FUNCTION_URL
   

Effectuer un nettoyage

Une fois le tutoriel terminé, vous pouvez supprimer tous les éléments que vous avez créés afin d'éviter tous frais supplémentaires.

Terraform vous permet de supprimer toutes les ressources définies dans le fichier de configuration en exécutant la commande terraform destroy dans le répertoire nodejs-docs-samples/functions/ contenant votre fichier main.tf:

terraform destroy

Saisissez yes pour autoriser Terraform à supprimer vos ressources.